From 39b3f09fdaa9904781f8f5376deb34cbd0168ad6 Mon Sep 17 00:00:00 2001
From: dsaf <ghostyn678+git@gmail.com>
Date: Fri, 20 Mar 2026 00:52:04 -0300
Subject: [PATCH] net-im/endcord: add 1.4.0

Signed-off-by: dsaf <ghostyn678+git@gmail.com>
---
 net-im/endcord/Manifest             |  1 +
 net-im/endcord/endcord-1.4.0.ebuild | 93 +++++++++++++++++++++++++++++
 net-im/endcord/endcord-9999.ebuild  |  3 +
 3 files changed, 97 insertions(+)
 create mode 100644 net-im/endcord/endcord-1.4.0.ebuild

diff --git a/net-im/endcord/Manifest b/net-im/endcord/Manifest
index 7c66e4f712..d9a8756569 100644
--- a/net-im/endcord/Manifest
+++ b/net-im/endcord/Manifest
@@ -1 +1,2 @@
 DIST endcord-1.3.0.tar.gz 776077 BLAKE2B efd535d64d97e553ae984ce38ce537c814561a0f4f7794e4b2619abd7ff09aef80e5d950ad86e9380c63d7bf4459654a746e19e77a880cab945b28104a13fb1e SHA512 e64f941314031f29793b1ef6d6c05ebcd7e6b8c0b6efa86edc5a77879c51c38498ddc360cbc8cfde1a41e9d4e637d6674d5d60960fd38610423c1aa5b648852f
+DIST endcord-1.4.0.tar.gz 798652 BLAKE2B 966625c8f7969c1464a8dd7729f2181947befc865b0df416d3b16dd0eeb84ef443bbbbe0de038997d827733ae5ba120f1f09e7ae6138eedf130093aeb8a83ae9 SHA512 3d0fdd19800170f7446a8a4cc0b827420599c0db77f7e528dcca3fb295fb3492d42f02a549bc6f72bc240a3fb2d21430a5f9a88d2853f1835bdc263ba8dcc80a
diff --git a/net-im/endcord/endcord-1.4.0.ebuild b/net-im/endcord/endcord-1.4.0.ebuild
new file mode 100644
index 0000000000..89d68b84df
--- /dev/null
+++ b/net-im/endcord/endcord-1.4.0.ebuild
@@ -0,0 +1,93 @@
+# Copyright 2026 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_EXT=1
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{12..14} )
+
+inherit distutils-r1 optfeature wrapper
+
+DESCRIPTION="Feature rich Discord TUI client"
+HOMEPAGE="https://github.com/sparklost/endcord"
+
+if [[ ${PV} == *9999 ]]; then
+	inherit git-r3
+	EGIT_REPO_URI="https://github.com/sparklost/endcord.git"
+else
+	SRC_URI="https://github.com/sparklost/endcord/archive/refs/tags/${PV}.tar.gz -> ${P}.tar.gz"
+	KEYWORDS="~amd64"
+fi
+
+LICENSE="GPL-3"
+SLOT=0
+
+IUSE="media"
+
+BDEPEND="
+	>=dev-python/cython-3.2.4[${PYTHON_USEDEP}]
+"
+RDEPEND="
+	>=dev-python/emoji-2.15.0[${PYTHON_USEDEP}]
+	>=dev-python/filetype-1.2.0[${PYTHON_USEDEP}]
+	>=dev-python/numpy-2.4.3[${PYTHON_USEDEP}]
+	|| (
+		>=dev-python/orjson-3.11.7[${PYTHON_USEDEP}]
+		dev-python/ujson[${PYTHON_USEDEP}]
+	)
+	>=dev-python/protobuf-7.34.0[${PYTHON_USEDEP}]
+	>=dev-python/pycryptodome-3.23.0[${PYTHON_USEDEP}]
+	>=dev-python/pysocks-1.7.1[${PYTHON_USEDEP}]
+	>=dev-python/python-socks-2.8.1[${PYTHON_USEDEP}]
+	>=dev-python/qrcode-8.2[${PYTHON_USEDEP}]
+	>=dev-python/soundcard-0.4.5[${PYTHON_USEDEP}]
+	>=dev-python/soundfile-0.13.1[${PYTHON_USEDEP}]
+	>=dev-python/urllib3-2.6.3[${PYTHON_USEDEP}]
+	>=dev-python/websocket-client-1.9.0[${PYTHON_USEDEP}]
+	media? (
+		>=dev-python/pynacl-1.6.2[${PYTHON_USEDEP}]
+		>=dev-python/pillow-12.1.1[${PYTHON_USEDEP}]
+		>=dev-python/av-16.1.0[${PYTHON_USEDEP}]
+	)
+"
+
+PATCHES=( "${FILESDIR}/${PN}-1.4.0-flags.patch" )
+
+DOCS=( README.md docs/ )
+
+python_install() {
+	distutils-r1_python_install
+
+	python_domodule ${PN}
+
+	exeinto /usr/libexec/${PN}
+	doexe main.py
+
+	make_wrapper ${PN} \
+		"${EPYTHON} ${EPREFIX}/usr/libexec/${PN}/main.py"
+}
+
+pkg_postinst() {
+	optfeature "clipboard support on X11" x11-misc/xclip
+	optfeature "clipboard support on Wayland" gui-apps/wl-clipboard
+
+	optfeature "file dialog when uploading" \
+		app-misc/yazi \
+		gnome-extra/zenity \
+		kde-apps/kdialog
+
+	optfeature "spellchecking (requires aspell dictionary such as aspell-en)" \
+		app-text/aspell
+
+	optfeature "install and update extensions from other sources" \
+		dev-vcs/git
+
+	optfeature "YouTube support" net-misc/yt-dlp
+	optfeature "play YouTube videos in native player (non-ASCII support)" media-video/mpv
+
+	optfeature "store token in system keyring (requires gnome-keyring running under dbus)" \
+		app-crypt/libsecret
+
+	optfeature "round notification images" media-gfx/imagemagick
+}
diff --git a/net-im/endcord/endcord-9999.ebuild b/net-im/endcord/endcord-9999.ebuild
index 680518a3f6..89d68b84df 100644
--- a/net-im/endcord/endcord-9999.ebuild
+++ b/net-im/endcord/endcord-9999.ebuild
@@ -80,6 +80,9 @@ pkg_postinst() {
 	optfeature "spellchecking (requires aspell dictionary such as aspell-en)" \
 		app-text/aspell
 
+	optfeature "install and update extensions from other sources" \
+		dev-vcs/git
+
 	optfeature "YouTube support" net-misc/yt-dlp
 	optfeature "play YouTube videos in native player (non-ASCII support)" media-video/mpv