diff --git a/media-sound/fooyin/Manifest b/media-sound/fooyin/Manifest
index b25e54717a..4dd480098d 100644
--- a/media-sound/fooyin/Manifest
+++ b/media-sound/fooyin/Manifest
@@ -1 +1,2 @@
+DIST fooyin-0.10.0.tar.gz 2994465 BLAKE2B 60ff3b87f4e78dbee92e6a3a061a04b705690ae114e833f0a9789a4921f253724b03c264308abdb7e24b6fb66e03749ad8471558381958c433a2ab6c3b00e165 SHA512 8bd88a845655232b4bc3bdc4c04f8167e2f39cbaece8ea2ccfe5cac5a2395dad8c1debcee8d02b8398e746b6fde95745ca76c19ea9a903cf880b27e7dbf5bc60
 DIST fooyin-0.9.2.tar.gz 2103435 BLAKE2B 77a3b290088a50d4d1757e10d66d0942245bc340d277e3292d2132221160b2f731978907c0e88bbfb7c706dd6b42ac630027f9e92fe19fbbeff47d541f3f2640 SHA512 328b30277ad2dba081e90bfeb6d0122098a83627f6787c6c986ce4b214f94ee22a65d2f94cc391a2652b2cc77f66a88e4dfa5e714e3f862aed6384b7943f09ea
diff --git a/media-sound/fooyin/fooyin-0.10.0.ebuild b/media-sound/fooyin/fooyin-0.10.0.ebuild
new file mode 100644
index 0000000000..7691dc3fc6
--- /dev/null
+++ b/media-sound/fooyin/fooyin-0.10.0.ebuild
@@ -0,0 +1,81 @@
+# Copyright 2026 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit cmake xdg
+
+DESCRIPTION="A customizable music player, Qt clone of foobar2000"
+HOMEPAGE="https://www.fooyin.org/"
+
+if [[ ${PV} == *9999* ]]; then
+	inherit git-r3
+	EGIT_REPO_URI="https://github.com/fooyin/fooyin.git"
+else
+	SRC_URI="
+		https://github.com/fooyin/fooyin/archive/refs/tags/v${PV}.tar.gz
+			-> ${P}.tar.gz
+	"
+	KEYWORDS="~amd64"
+fi
+
+LICENSE="GPL-3"
+SLOT="0"
+
+IUSE="alsa +archive openmpt +pipewire +replaygain sdl sndfile test"
+RESTRICT="!test? ( test )"
+REQUIRED_USE="
+	|| ( alsa pipewire sdl )
+"
+
+RDEPEND="
+	dev-libs/icu:=
+	dev-libs/kdsingleapplication
+	dev-libs/qcoro[network]
+	dev-qt/qtbase:6[concurrent,dbus,gui,network,sql,widgets]
+	dev-qt/qtimageformats:6
+	dev-qt/qtsvg:6
+	media-libs/taglib:=
+	media-video/ffmpeg:=
+	alsa? ( media-libs/alsa-lib )
+	archive? ( app-arch/libarchive:= )
+	openmpt? ( media-libs/libopenmpt )
+	pipewire? ( media-video/pipewire:= )
+	replaygain? ( media-libs/libebur128:= )
+	sdl? ( media-libs/libsdl2 )
+	sndfile? ( media-libs/libsndfile )
+"
+DEPEND="${RDEPEND}"
+BDEPEND="
+	dev-qt/qttools:6[linguist]
+	test? ( dev-cpp/gtest )
+"
+
+src_prepare() {
+	sed -i CMakeLists.txt \
+		-e "s|/doc/${PN}|/doc/${PF}|g" \
+		-e '/option(BUILD_TESTING/aenable_testing()' \
+		|| die
+
+	cmake_src_prepare
+}
+
+# libgme dependency can currently not be satisfied,
+# so building the input plugin is unconditionally disabled for now
+src_configure() {
+	local mycmakeargs=(
+		-DBUILD_ALSA=$(usex alsa)
+		-DBUILD_TESTING=$(usex test)
+		-DBUILD_CCACHE=OFF
+		-DCMAKE_DISABLE_FIND_PACKAGE_LIBGME=ON
+		-DINSTALL_HEADERS=ON
+		$(cmake_use_find_package archive LibArchive)
+		$(cmake_use_find_package openmpt OpenMpt)
+		$(cmake_use_find_package pipewire PipeWire)
+		$(cmake_use_find_package replaygain Ebur128)
+		$(cmake_use_find_package sdl SDL2)
+		$(cmake_use_find_package sndfile SndFile)
+	)
+
+	cmake_src_configure
+}
diff --git a/media-sound/fooyin/fooyin-9999.ebuild b/media-sound/fooyin/fooyin-9999.ebuild
index cd52970c03..7691dc3fc6 100644
--- a/media-sound/fooyin/fooyin-9999.ebuild
+++ b/media-sound/fooyin/fooyin-9999.ebuild
@@ -1,4 +1,4 @@
-# Copyright 2025 Gentoo Authors
+# Copyright 2026 Gentoo Authors
 # Distributed under the terms of the GNU General Public License v2
 
 EAPI=8