mirror of
https://github.com/gentoo-mirror/guru.git
synced 2026-04-07 03:10:15 -04:00
8bcc26e21a
* add SLOT to dependencies * wire up tests * fix displayed version * add manpages * remove LICENSE from doc dir * sync -9999, which is tag v2.4 at the moment Acked-by: Quincy Fleming <quincyf467@protonmail.com> Part-of: https://github.com/gentoo/guru/pull/415 Closes: https://github.com/gentoo/guru/pull/415 Signed-off-by: Lucio Sauer <watermanpaint@posteo.net>
47 lines
978 B
Bash
47 lines
978 B
Bash
# Copyright 2023-2026 Gentoo Authors
|
|
# Distributed under the terms of the GNU General Public License v2
|
|
|
|
EAPI=8
|
|
|
|
inherit toolchain-funcs
|
|
|
|
DESCRIPTION="Tool to communicate with Qualcomm System On a Chip bootroms"
|
|
HOMEPAGE="https://github.com/linux-msm/qdl"
|
|
SRC_URI="https://github.com/linux-msm/qdl/archive/refs/tags/v${PV}.tar.gz -> ${P}.tar.gz"
|
|
|
|
LICENSE="BSD"
|
|
SLOT="0"
|
|
KEYWORDS="~amd64"
|
|
|
|
DEPEND="
|
|
dev-libs/libusb:1
|
|
dev-libs/libxml2:=
|
|
"
|
|
RDEPEND="${DEPEND}"
|
|
|
|
BDEPEND="
|
|
sys-apps/help2man
|
|
virtual/pkgconfig
|
|
"
|
|
|
|
src_compile() {
|
|
# $(VERSION) needs to be consistent in all make invocations
|
|
export VERSION="${PV}"
|
|
|
|
local PKG_CONFIG="$(tc-getPKG_CONFIG)"
|
|
emake CC="$(tc-getCC)" \
|
|
CFLAGS="${CFLAGS} $(${PKG_CONFIG} --cflags libxml-2.0 libusb-1.0 || die)" \
|
|
LDFLAGS="${LDFLAGS} $(${PKG_CONFIG} --libs libxml-2.0 libusb-1.0 || die)"
|
|
emake manpages
|
|
}
|
|
|
|
src_test() {
|
|
emake tests
|
|
}
|
|
|
|
src_install() {
|
|
emake prefix="${EPREFIX}/usr" DESTDIR="${D}" install
|
|
doman *.1
|
|
einstalldocs
|
|
}
|