net-nntp/pan: revbump for RDEPEND, switch from local to eclass var.

Didn't revbump when I updated RDEPEND for QA, so doing it now. Switching local build_dir to BUILD_DIR on feedback from antecrescent. See-Also: ae98af00cb Signed-off-by: Joe Kappus <joe@wt.gd>
2026-04-07 03:10:15 -04:00 · 2024-06-09 12:26:08 -04:00
parent 6e321e9189
commit 01f31c3b47
2 changed files with 133 additions and 0 deletions
--- a/net-nntp/pan/pan-0.158-r1.ebuild
+++ b/net-nntp/pan/pan-0.158-r1.ebuild
@@ -0,0 +1,58 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+inherit autotools gnome2
+
+DESCRIPTION="A newsreader for GNOME"
+HOMEPAGE="https://gitlab.gnome.org/GNOME/pan/"
+SRC_URI="https://gitlab.gnome.org/GNOME/pan/-/archive/v${PV}/${PN}-v${PV}.tar.bz2"
+S="${WORKDIR}/pan-v${PV}"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64 ~x86"
+IUSE="dbus gnome-keyring libnotify nls spell ssl"
+
+DEPEND="
+	>=dev-libs/glib-2.26:2
+	dev-libs/gmime:3.0
+	>=x11-libs/gtk+-3.00:3
+	gnome-keyring? (
+		>=app-crypt/gcr-3.20
+		>=app-crypt/libsecret-0.20
+	)
+	libnotify? ( >=x11-libs/libnotify-0.4.1:0= )
+	spell? (
+		>=app-text/enchant-2.2.3:2
+		>=app-text/gtkspell-3.0.10:3 )
+	ssl? ( >=net-libs/gnutls-3:0= )
+	>=sys-libs/zlib-1.2.0
+	x11-libs/cairo
+	x11-libs/gdk-pixbuf
+	x11-libs/pango
+"
+RDEPEND="${DEPEND}"
+BDEPEND="
+	app-text/yelp-tools
+	>=sys-devel/gettext-0.19.7
+	virtual/pkgconfig
+"
+
+src_prepare() {
+	default
+	eautoreconf
+}
+
+src_configure() {
+	local myconf=(
+		$(use_with dbus) \
+		$(use_enable gnome-keyring gkr) \
+		$(use_enable nls) \
+		$(use_with spell gtkspell) \
+		$(use_enable libnotify) \
+		$(use_with ssl gnutls)
+	)
+
+	gnome2_src_configure "${myconf[@]}"
+}
--- a/net-nntp/pan/pan-0.159-r1.ebuild
+++ b/net-nntp/pan/pan-0.159-r1.ebuild
@@ -0,0 +1,75 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+inherit cmake gnome2
+
+DESCRIPTION="A newsreader for GNOME"
+HOMEPAGE="https://gitlab.gnome.org/GNOME/pan/"
+SRC_URI="https://gitlab.gnome.org/GNOME/pan/-/archive/v${PV}/${PN}-v${PV}.tar.bz2"
+S="${WORKDIR}/pan-v${PV}"
+
+LICENSE="GPL-2"
+SLOT="0"
+
+KEYWORDS="~amd64 ~arm64 ~x86"
+IUSE="dbus gnome-keyring libnotify spell ssl"
+
+DEPEND="
+	>=dev-libs/glib-2.26:2
+	dev-libs/gmime:3.0
+	>=x11-libs/gtk+-3.00:3
+	gnome-keyring? (
+		>=app-crypt/gcr-3.20
+		>=app-crypt/libsecret-0.20
+	)
+	libnotify? ( >=x11-libs/libnotify-0.4.1:0= )
+	spell? (
+		>=app-text/enchant-2.2.3:2
+		>=app-text/gtkspell-3.0.10:3 )
+	ssl? ( >=net-libs/gnutls-3:0= )
+	>=sys-libs/zlib-1.2.0
+	x11-libs/cairo
+	x11-libs/gdk-pixbuf
+	x11-libs/pango
+"
+RDEPEND="${DEPEND}"
+BDEPEND="
+	app-text/yelp-tools
+	>=sys-devel/gettext-0.19.7
+	virtual/pkgconfig
+"
+
+src_prepare() {
+	cmake_src_prepare
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-DWANT_DBUS=$(usex dbus) \
+		-DWANT_GKR=$(usex gnome-keyring) \
+		-DWANT_GTKSPELL=$(usex spell) \
+		-DWANT_NOTIFY=$(usex libnotify) \
+		-DWANT_GNUTLS=$(usex ssl)
+	)
+
+	cmake_src_configure
+}
+
+src_install() {
+	cmake_src_install
+
+	# Since cmake apparently doesn't include the below automatically
+	dolib.so "${BUILD_DIR}/pan/data/libdata.so"
+	dolib.so "${BUILD_DIR}/pan/data-impl/libdata-impl.so"
+	dolib.so "${BUILD_DIR}/pan/general/libgeneralutils.so"
+	dolib.so "${BUILD_DIR}/pan/tasks/libtasks.so"
+	dolib.so "${BUILD_DIR}/pan/usenet-utils/libusenet-utils.so"
+
+
+}
+
+src_test() {
+	# not doing tests. Bug #933860
+	einfo "Skipping tests..."
+}