media-gfx/pdf4qt: add 1.5.3.1

Also:
- add USE=debug
- revbump 1.5.3.1 {=>-r1} (should have been done in cdb4b8754)

Signed-off-by: Alexander Golubev <fatzer2@gmail.com>

media-gfx/pdf4qt/Manifest

@@ -1 +1,2 @@
 DIST PDF4QT-1.5.1.0.tar.gz 4560158 BLAKE2B ac479bae1dbae3e3b065ded2e9991c5cd4c2a86f172110c50adf2dd3c04e3cc55b963764a569e8e3770172e6a5c3a1d5cead4b288db4a7dbe4bc009bf67bcbd9 SHA512 483980223e1dd365cb850ac09de10deb8a9ef676a642028ce55bd2c4f315619eb0b4721ad217476c8ff95ab53bbbe49bb7db2c2aae1e8ac4d8f3bfbac9519abc
+DIST PDF4QT-1.5.3.1.tar.gz 7346956 BLAKE2B 1ac79d545e505105431b74978d60ff77d09f81db91a1514136225de19121b8d78e331b83bd0cd3c463f9a1e30c3c04b27427ab8d55960de049ab31aa3a41000a SHA512 efbebf031104aced080624f59bc42c1a2d53f32a2d69d1e031015c51dca22dd85e84692a8dee7fbacc87a413e20fb572a9e51e26afcc77c13af2fd1d0a609e33

media-gfx/pdf4qt/pdf4qt-1.5.3.1.ebuild

@@ -0,0 +1,64 @@
+# Copyright 2024-2026 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+inherit cmake flag-o-matic xdg
+
+DESCRIPTION="Open source PDF WYSIWYG editor based on Qt"
+HOMEPAGE="https://jakubmelka.github.io/"
+MY_PN="${PN^^}"
+if [[ ${PV} == 9999 ]]; then
+	inherit git-r3
+	EGIT_REPO_URI="https://github.com/JakubMelka/${MY_PN}"
+else
+	MY_P="${MY_PN}-${PV}"
+	SRC_URI="https://github.com/JakubMelka/${MY_PN}/archive/refs/tags/v${PV}.tar.gz
+		-> ${MY_P}.tar.gz"
+	KEYWORDS="~amd64"
+	S=${WORKDIR}/${MY_P}
+fi
+
+LICENSE="MIT"
+SLOT="0"
+IUSE="debug test"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	dev-cpp/tbb:=
+	dev-libs/openssl:=
+	dev-qt/qtbase:6[gui,widgets,xml]
+	dev-qt/qtspeech:6
+	dev-qt/qtsvg:6
+	>=media-libs/blend2d-0.20:=
+	media-libs/freetype
+	media-libs/lcms:2
+	media-libs/libjpeg-turbo:=
+	media-libs/openjpeg:=
+	virtual/zlib:=
+"
+DEPEND="$RDEPEND
+	test? ( dev-qt/qtbase:6[test] )
+"
+
+DOCS=( NOTES.txt README.md RELEASES.txt )
+PATCHES=(
+	"${FILESDIR}/${PN}-1.5.1.0-Make-building-of-tests-optional.patch"
+	"${FILESDIR}/${PN}-1.5.1.0-Make-runtime-respect-cmake-s-plugin-dir-settings.patch"
+	"${FILESDIR}/${PN}-1.5.1.0-Fix-translation-install-path-on-nix.patch"
+)
+
+src_configure() {
+	# without NDEBUG it shows annoying warning about keyboard accelerators reuse
+	use debug || append-cxxflags -DNDEBUG
+
+	local mycmakeargs=(
+		-DPDF4QT_INSTALL_DEPENDENCIES=OFF
+		-DPDF4QT_INSTALL_TO_USR=OFF
+		-DPDF4QT_BUILD_TESTS="$(usex test)"
+	)
+	cmake_src_configure
+}
+
+src_test() {
+	"${BUILD_DIR}"/bin/UnitTests || die "tests failed"
+}

media-gfx/pdf4qt/pdf4qt-9999.ebuild

@@ -2,7 +2,7 @@
 # Distributed under the terms of the GNU General Public License v2
 
 EAPI=8
-inherit cmake xdg
+inherit cmake flag-o-matic xdg
 
 DESCRIPTION="Open source PDF WYSIWYG editor based on Qt"
 HOMEPAGE="https://jakubmelka.github.io/"
@@ -20,7 +20,7 @@ fi
 
 LICENSE="MIT"
 SLOT="0"
-IUSE="test"
+IUSE="debug test"
 RESTRICT="!test? ( test )"
 
 RDEPEND="
@@ -48,6 +48,9 @@ PATCHES=(
 )
 
 src_configure() {
+	# without NDEBUG it shows annoying warning about keyboard accelerators reuse
+	use debug || append-cxxflags -DNDEBUG
+
 	local mycmakeargs=(
 		-DPDF4QT_INSTALL_DEPENDENCIES=OFF
 		-DPDF4QT_INSTALL_TO_USR=OFF