media-libs/openxr-loader: add 1.1.54

Signed-off-by: Haelwenn (lanodan) Monnier <contact@hacktivis.me>

media-libs/openxr-loader/Manifest

@@ -1 +1,2 @@
 DIST openxr-loader-1.1.52.tar.gz 712802 BLAKE2B a49a2001a496b8bc866de1e2d7f0c68562d4489fcb5eaaadbac5a922481517825ae57eb2ebc3b74f135a700a86302e915090abf8c266f16060a70c49878b769f SHA512 e333abb28934883111a6760d7c4c956efb97b0b7ecec65a4e430010b7290c4b7af01a831ec798444293d29d84a91b74593c6a5d1f59fcbc958495ee9d0f7da78
+DIST openxr-loader-1.1.54.tar.gz 723031 BLAKE2B 5a527f04dbe96df2f3e225f727e97a3cabaadead4e80c2ffe63372c441a54be70a14823c8eae52b7d440e4ac91891daff7da1d32c40f75cfdaa663d50cc434fc SHA512 896b28a0ccdaf6819bf5fa7339dd40c7839a964fd33af16a0e3b5a1621779a27b7fb290fb4e5eba43b52af5737c7f62d3976b42ddd7f5f5e82ab23b2e3e218bb

media-libs/openxr-loader/openxr-loader-1.1.54.ebuild

@@ -0,0 +1,63 @@
+# Copyright 2020-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+MY_PN=OpenXR-SDK
+inherit cmake-multilib
+
+if [[ ${PV} == *9999* ]]; then
+	inherit git-r3
+	EGIT_REPO_URI="https://github.com/KhronosGroup/${MY_PN}.git"
+	SLOT="0"
+else
+	SRC_URI="https://github.com/KhronosGroup/${MY_PN}/archive/refs/tags/release-${PV}.tar.gz -> ${P}.tar.gz"
+	KEYWORDS="~amd64"
+	S="${WORKDIR}/${MY_PN}-release-${PV}"
+	SLOT="0/${PV}"
+fi
+
+DESCRIPTION="OpenXR loader"
+HOMEPAGE="https://github.com/KhronosGroup/OpenXR-SDK"
+
+LICENSE="Apache-2.0"
+
+IUSE="+wayland +X"
+REQUIRED_USE="|| ( wayland X )"
+
+DEPEND="
+	media-libs/vulkan-loader[${MULTILIB_USEDEP}]
+	media-libs/mesa[${MULTILIB_USEDEP}]
+	dev-libs/jsoncpp:=[${MULTILIB_USEDEP}]
+	wayland? (
+		dev-libs/wayland[${MULTILIB_USEDEP}]
+		dev-libs/wayland-protocols
+	)
+	X? (
+		x11-libs/libxcb[${MULTILIB_USEDEP}]
+		x11-libs/xcb-util-keysyms
+		x11-libs/libXrandr[${MULTILIB_USEDEP}]
+		x11-libs/libXxf86vm[${MULTILIB_USEDEP}]
+	)
+"
+RDEPEND="${DEPEND}"
+BDEPEND="wayland? ( dev-util/wayland-scanner )"
+
+src_prepare() {
+	sed -i 's;LICENSE_DEST share/doc/openxr;LICENSE_DEST ${CMAKE_INSTALL_DOCDIR};' CMakeLists.txt || die
+
+	cmake_src_prepare
+}
+
+multilib_src_configure() {
+	local mycmakeargs=(
+		-DBUILD_WITH_SYSTEM_JSONCPP=ON
+		-DBUILD_WITH_XLIB_HEADERS=$(usex X)
+		-DBUILD_WITH_XCB_HEADERS=$(usex X)
+		-DBUILD_WITH_WAYLAND_HEADERS=$(usex wayland)
+		-DBUILD_WITH_SYSTEM_JSONCPP=YES
+		-DPRESENTATION_BACKEND=$(usex X xlib wayland)
+	)
+
+	cmake_src_configure
+}