games-strategy/7k-ambition: add 3.2.7, drop 3.2.6

Signed-off-by: Tim Sviridov <Lt.Infiltrator@gmail.com>

games-strategy/7k-ambition/7k-ambition-3.2.7.ebuild

@@ -0,0 +1,79 @@
+# Copyright 1999-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit autotools desktop toolchain-funcs xdg
+
+if [[ ${PV} == *9999* ]]; then
+	inherit git-r3
+	EGIT_REPO_URI="https://git.code.sf.net/p/seven-kingdoms-ambition/code"
+	EGIT_BRANCH="next"
+else
+	SRC_URI="https://github.com/Infiltrator/${PN}/archive/refs/tags/v${PV}.tar.gz -> ${P}.tar.gz"
+	KEYWORDS="~amd64"
+fi
+
+DESCRIPTION="Seven Kingdoms: Ambition"
+HOMEPAGE="https://seven-kingdoms-ambition.sourceforge.io/"
+SRC_URI+=" https://sourceforge.net/projects/seven-kingdoms-ambition/files/${PN}.png/download -> ${PN}.png
+	music? ( https://www.7kfans.com/downloads/7kaa-music-2.15.tar.bz2 )
+"
+
+LICENSE="GPL-2
+		music? ( 7k-music )"
+SLOT="0"
+IUSE="+nls +multiplayer +music"
+RESTRICT="music? ( bindist ) mirror"
+
+DEPEND="
+	dev-libs/boost:=
+	nls? ( <=sys-devel/gettext-0.22.5-r2 )
+	multiplayer? (
+		net-libs/enet:1.3=
+		net-misc/curl:=
+	)
+	media-libs/libsdl2[X,video]
+	media-libs/openal:=
+"
+RDEPEND="${DEPEND}"
+
+src_unpack() {
+	if [[ ${PV} == *9999* ]]; then
+		git-r3_src_unpack
+	fi
+
+	default
+}
+
+src_prepare() {
+	default
+	eautoreconf
+}
+
+src_configure() {
+	local myeconfargs=(
+		$(use_enable nls)
+		$(use_enable multiplayer)
+	)
+	econf "${myeconfargs[@]}"
+}
+
+src_compile() {
+	emake AR="$(tc-getAR)"
+}
+
+src_install() {
+	default
+
+	if use music ; then
+		insinto "usr/share/${PN}/"
+		doins -r "${WORKDIR}/7kaa-music/MUSIC"
+
+		dodoc "${WORKDIR}/7kaa-music/README-Music.txt" "${WORKDIR}/7kaa-music/COPYING-Music.txt"
+	fi
+
+	doicon "${DISTDIR}/${PN}.png"
+
+	make_desktop_entry ${PN} "Seven Kingdoms: Ambition" /usr/share/pixmaps/${PN}.png Game
+}

games-strategy/7k-ambition/Manifest

@@ -1,2 +1,3 @@
+DIST 7k-ambition-3.2.7.tar.gz 63336653 BLAKE2B 63ef5cba37360d51d3d7dff9243c0b39598d3107c91bb9bef37297ff66a8fafcce761ee097034e0f2b4bbd94612dcace786646cd70aaaa34bb6df673a7232360 SHA512 b4183fbc59492f773f7a8d1be6004e2c2abac67c26a5c00d3e70b9796345740652585799d94a2ade5b864f8608f8aef560b218d6531eb15e283f982fd4184adb
 DIST 7k-ambition.png 203178 BLAKE2B 1feaeab6a4538a278578bdbd195d3b809472008fa8d691d564a27d05da3adcc1125f0eafe42c45dd28c8719c62397dedac2f2bf31276430e0e42be246a98f7be SHA512 33a4ed08facceb626f2dc3ed99c0e05b0e3898d2a800878be55520acbfeb2f4d71dfc9bc927b18aa24fb2bef5678674065a79c08fc8a8b44ecafe28d901b5c28
 DIST 7kaa-music-2.15.tar.bz2 20050332 BLAKE2B e051ee3071d79316ab5a8d9dbcde5047c551e398da7f4f857c4eaf6f60ec6b66eafb892372e05c4db837238dc2777bdbe9b57079c938b072fda2a250e423f627 SHA512 e2c7ce14dc6e50581dca9769f03167e59e4be19aa559bfc2a7acd277f72c060935f3158edc735711ce971924b105e8df5984c2c40da8d6f484625e5ce94a7f73