www-client/helium-bin: add 0.8.4.1

Signed-off-by: Jonas Frei <freijon@pm.me>

www-client/helium-bin/Manifest

@@ -1,2 +1,4 @@
 DIST helium-bin-0.8.3.1-amd64.tar.xz 109449704 BLAKE2B 2e09aad94c51847e49356ea4cbc9323f3eb2afdbef069cfe200400b905f56551993f562365a9741597f2c0ed2b65bb160caea5ad4909c7cf9b820ef329566b00 SHA512 8afd543ec561290a0012775fdc4ce1b88f135dff3d77290e45b279738fbed2cce25ebdf9c71d93bd13bbf1048320f3198863b1c22d3beb867cf4e897b6bbe9f9
 DIST helium-bin-0.8.3.1-arm64.tar.xz 103740556 BLAKE2B d5edbfa0790f1fdd60e7e2c265e12772f1e49291943ad992012722f511e1b6e9a2130640b2a7f92f5cc27f36bd0ea14673e843e64f0c13f4f4c4857a3222b74a SHA512 43d943686c24ad28b4cb32464a0d11befd741429ce6263a64140475007a405b0f46439a7789dac3ee1bf1b535eab6bf3b46fcf4ebb70e87ec7c9923af6c819b6
+DIST helium-bin-0.8.4.1-amd64.tar.xz 109480216 BLAKE2B 70878dac273ffeca7d15d6563c165bc60f1262c91567291356c524c3eafe78c464162ab06501f797c5e0322c56ef7e077020af117ff8572050036b176593db0d SHA512 ec66c275aa4a88249093dd3cf9ed0b267c9bbe2d3aa2bc8b399dcfd6cd351c2ade9fbd9e9df2be9a53c74337da29e27eb4229eeb1e7bc799ef695700ff92fed1
+DIST helium-bin-0.8.4.1-arm64.tar.xz 103762808 BLAKE2B 5e1e729c6f9b5f47f1478b77feb995a9a752c0c49b29146fb6fb3e5a7263e35ea11181485d011480aea22ce12ec027dda228efb14df2a6ea48e771890ab9bd84 SHA512 3a503a0d2ceac38b052fc1a5bb43717e3ba1e8066c4121f5d51a18eb0aec81f219e42613c74c2831e510f82761cd0e29ded60c9fddde147d4a4cde4ab88d3c1f

www-client/helium-bin/helium-bin-0.8.4.1.ebuild

@@ -0,0 +1,113 @@
+# Copyright 2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+CHROMIUM_LANGS="af am ar bg bn ca cs da de el en-GB en-US es-419 es
+	et fa fi fil fr gu he hi hr hu id it ja kn ko lt lv ml mr ms nb nl
+	pl pt-BR pt-PT ro ru sk sl sr sv sw ta te th tr uk ur vi zh-CN zh-TW"
+
+inherit chromium-2 desktop pax-utils xdg
+
+DESCRIPTION="Private, fast, and honest web browser based on Chromium"
+HOMEPAGE="https://helium.computer/"
+
+MY_PN="helium"
+MY_P="${MY_PN}-${PV}"
+
+if [[ ${ARCH} == amd64 ]] ; then
+	ARCH_TXT="x86_64"
+elif [[ ${ARCH} == arm64 ]] ; then
+	ARCH_TXT="${ARCH}"
+fi
+
+SRC_URI="
+amd64? ( https://github.com/imputnet/${MY_PN}-linux/releases/download/${PV}/${MY_P}-x86_64_linux.tar.xz -> ${P}-amd64.tar.xz )
+arm64? ( https://github.com/imputnet/${MY_PN}-linux/releases/download/${PV}/${MY_P}-arm64_linux.tar.xz -> ${P}-arm64.tar.xz )
+"
+
+S=${WORKDIR}
+
+LICENSE="GPL-3 BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64"
+
+IUSE="qt6 selinux"
+
+RESTRICT="bindist mirror strip"
+
+RDEPEND="
+	>=app-accessibility/at-spi2-core-2.46.0:2
+	app-misc/ca-certificates
+	dev-libs/expat
+	dev-libs/glib:2
+	dev-libs/nspr
+	>=dev-libs/nss-3.26
+	media-fonts/liberation-fonts
+	media-libs/alsa-lib
+	media-libs/mesa[gbm(+)]
+	net-misc/curl
+	net-print/cups
+	sys-apps/dbus
+	sys-libs/glibc
+	sys-libs/libcap
+	x11-libs/cairo
+	x11-libs/gdk-pixbuf:2
+	|| (
+		x11-libs/gtk+:3[X]
+		gui-libs/gtk:4[X]
+	)
+	x11-libs/libdrm
+	>=x11-libs/libX11-1.5.0
+	x11-libs/libXcomposite
+	x11-libs/libXdamage
+	x11-libs/libXext
+	x11-libs/libXfixes
+	x11-libs/libXrandr
+	x11-libs/libxcb
+	x11-libs/libxkbcommon
+	x11-libs/libxshmfence
+	x11-libs/pango
+	x11-misc/xdg-utils
+	qt6? ( dev-qt/qtbase:6[gui,widgets] )
+	selinux? ( sec-policy/selinux-chromium )
+"
+
+QA_PREBUILT="*"
+
+pkg_setup() {
+	chromium_suid_sandbox_check_kernel_config
+}
+
+# Skip unpack, we're doing it during install
+src_unpack() {
+	:
+}
+
+src_install() {
+	dodir "opt" || die
+	cd "${ED}/opt/" || die
+
+	# Not possible to unpack to target folder, so: unpack, then mv
+	unpack "${P}-${ARCH}.tar.xz"
+	mv ${MY_P}-${ARCH_TXT}_linux ${MY_PN} || die
+
+	cd "${MY_PN}" || die
+
+	pushd "locales" > /dev/null || die
+	# Remove empty .info files
+	rm *.info || die
+	chromium_remove_language_paks
+	popd > /dev/null || die
+
+	rm "libqt5_shim.so" || die
+	if ! use qt6; then
+		rm "libqt6_shim.so" || die
+	fi
+
+	newicon -s 256 "product_logo_256.png" ${MY_PN}.png
+	domenu "${FILESDIR}/${MY_PN}.desktop"
+	dobin "${FILESDIR}/${MY_PN}"
+
+	pax-mark m "${MY_PN}"
+}