gui-libs/mir: add 2.22.1

Signed-off-by: Takuya Wakazono <pastalian46@gmail.com>

gui-libs/mir/Manifest

@@ -1,2 +1,3 @@
 DIST mir-2.21.1.tar.gz 6879903 BLAKE2B 644d41be226b7ecf673b26bcc14b52d693b11bc2d63775f591e7332d854b0d3725ca23a0747e7ea53b2928ea5f3221376d74fd6b5aea0997f392e2892028a12e SHA512 36bfef3462e2428d608e5b6e4ba910d4c0c1db6d4614cc46ebb322314230b785e308b120bf5a69e60aad6c6e04c369a48d7323cccc1d4a389dc757c69ffcff40
 DIST mir-2.22.0.tar.gz 6946641 BLAKE2B 148e827296786c280afcc431b473d67c08fc53bcf5ce5ec68d0fa7d97a203b58f5fd4c2c82aebf0ba979d26704f91395748e50f7aca0edb1bc14cde0effe1a5c SHA512 6f6236f7894fb70ce666e98cdcfcc76fbc538b881d6bb3e58db224fe2ae63a0dc179406a2ff7b3b2fbf3db7b55d2ae00b400ac533d33ac66630bfba56f1c4a12
+DIST mir-2.22.1.tar.gz 6946738 BLAKE2B 81cc7510e1957c9ffd1880ffee04adc6caa28ec9d841ca017e54edcb5720076124008f0905c4bd285905c28edf5bbf3a4cfbe0dd4e60270b99e4779065f80677 SHA512 2a861fd51c32ac7d5c62f020de8e1499c2ddd99f63ac10654ccfffba9b72a2bce382a34fe700418d29fbc29ce7af925b7cad6d5e5a5fe27bb07b3247924a2493

gui-libs/mir/mir-2.22.1.ebuild

@@ -0,0 +1,86 @@
+# Copyright 2024-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit cmake xdg
+
+DESCRIPTION="Set of libraries for building Wayland based shells"
+HOMEPAGE="https://canonical.com/mir"
+SRC_URI="https://github.com/canonical/mir/archive/refs/tags/v${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="|| ( GPL-2 GPL-3 ) || ( LGPL-2.1 LGPL-3 )"
+SLOT="0/$(ver_cut 1-2)"
+KEYWORDS="~amd64"
+IUSE="examples test wayland X"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	dev-cpp/glibmm:2
+	dev-cpp/libxmlpp:2.6
+	dev-cpp/yaml-cpp:=
+	dev-libs/boost:=
+	dev-libs/glib:2
+	dev-libs/libinput:=
+	dev-libs/wayland
+	dev-util/lttng-ust:=
+	media-libs/freetype
+	media-libs/libdisplay-info:=
+	media-libs/libepoxy
+	media-libs/libglvnd
+	media-libs/mesa
+	sys-apps/util-linux
+	x11-libs/libXcursor
+	x11-libs/libdrm
+	x11-libs/libxcb:=
+	x11-libs/libxkbcommon
+	x11-libs/pixman
+	virtual/libudev:=
+	X? ( x11-libs/libX11 )
+"
+DEPEND="
+	${RDEPEND}
+	media-libs/glm
+"
+BDEPEND="
+	dev-util/gdbus-codegen
+	virtual/pkgconfig
+	test? (
+		dev-cpp/gtest
+		dev-util/umockdev
+		x11-base/xwayland
+	)
+"
+
+PATCHES=(
+	# bug 932786
+	"${FILESDIR}/${PN}-2.17.0-remove-debug-flags.patch"
+	"${FILESDIR}/${PN}-2.20.0-remove-tests.patch"
+)
+
+src_prepare() {
+	cmake_src_prepare
+	use examples || cmake_comment_add_subdirectory examples/ examples/tests/
+}
+
+src_configure() {
+	local platforms=( gbm-kms atomic-kms )
+	use wayland && platforms+=( wayland )
+	use X && platforms+=( x11 )
+
+	local mycmakeargs=(
+		# wlcs is not packaged
+		-DMIR_ENABLE_WLCS_TESTS=OFF
+		-DMIR_ENABLE_TESTS="$(usex test)"
+		-DMIR_FATAL_COMPILE_WARNINGS=OFF
+		-DMIR_PLATFORM="$(IFS=';'; echo "${platforms[*]}")"
+		-DMIR_ENABLE_RUST=OFF
+	)
+	use test && mycmakeargs+=(
+		# likely will not work in build environment
+		-DMIR_BUILD_PERFORMANCE_TESTS=OFF
+		-DMIR_BUILD_PLATFORM_TEST_HARNESS=OFF
+		-DMIR_BUILD_UNIT_TESTS=OFF
+	)
+	cmake_src_configure
+}